Running FTA Modulae Demo from CFFA3000

See Part 2 for more/better results

Because the FTA Modulae demo uses the IWM registers directly (unlike Nucleus which uses Smartport calls), the demo as written will not load on anything other than a 3.5" floppy disk. I don't like these, and will generally only use a CFFA3000. Poor me, I want giga-smooth scrolling from CFFA3000. The solution is to start by examining Modulae's loader. With assistance from LOADER2.S and other XMAS-Demo sources from FTA 'Gifts' disks, and judicious Block Warden based insertions of BRKs, I quickly got something like this, if you care to read:

Modulae Loader Disassembly Notes

.. I spent some time researching how the IWM registers work, and how ACS Cruncher works (apparently it's a derivative of a Commodore 64 cruncher called TCS cruncher?), but eventually knocked that off, because the goal is just to boot this mess on solid-state hardware.

From there, I put together a plan to proceed. I didn't care to patch/re-crunch the code at $9400 although that would have been more elegant. So what I ended up doing was:

Find some empty space in the first two disk blocks and insert code to load my new loader from disk block $0600 at $9000:

	   0BD4 - 38         - SEC
	   0BD5 - FB         - XCE
	   0BD6 - E2 30      - SEP #$30
	   0BD8 - 20 0D C5   - JSR $C50D
	   0BDB - 01
	   0BDC - E1 0B
	   0BDE - 4C 00 90   - JMP $9000
	   0BE1 - 03 01
	   0BE3 - 00 90
	   0BE5 - 00 06 00

Used Block Warden to set these bytes directly on block $0001, starting at $01D4

Make Modulae boot0 execute my new patcher/loader instead of jumping into $9400:
```
           08F6 - 4C D4 0B
```
Used Block Warden to set these bytes directly on block $0001, starting at $00F6

Write patcher/new loader to load at $9000 and relocate itself over the old loader at $9C6F:

         org $9000

         clc
         xce
         rep #$30
         ldx #$0000
relo     lda patch,x
         sta $9C6F,x
         inx
         inx
         cpx #pend-patch2
         bcc relo

* TEST area to insert other stuff
         nop
         nop
         nop
         nop
         nop
         nop
         nop
         nop
* TEST end

         jmp $9478

patch    = *

* new regular smartport loader to replace Load_Segment
         org $9C6F
patch2
         pha
         sec
         xce
         sep #$30
         lda #$41
         sta $C029
         lda #$F0
         sta $C022
         clc
         xce
         rep #$30
         pla

         sta $00
         lda ($00)
         sta blknum
]loadlp  inc $00
         inc $00
         lda ($00)
         sta buffer
         inc $00
         inc $00
         lda ($00)
         sta buffer+2
         inc $00
         inc $00
         lda ($00)
         beq ret
         lsr
         tay
         inc $00
         inc $00
]blklp   phy
         sec
         xce
         sep #$30

* TEST show info about the block we're about to read
         lda blknum+1
         jsr $FDDA
         lda blknum
         jsr $FDDA

         lda #$A0
         jsr $FDED
         lda #$C0
         jsr $FDED
         lda #$A0
         jsr $FDED

         lda buffer+2
         jsr $FDDA
         lda buffer+1
         jsr $FDDA
         lda buffer
         jsr $FDDA

         lda #$A0
         jsr $FDED
         lda $01
         jsr $FDDA
         lda $00
         jsr $FDDA

         lda #$8D
         jsr $FDED
* TEST end

         jsr $C50D
         db  $41
         adrl params

         clc
         xce
         rep #$30
         inc buffer+1
         inc buffer+1
         inc blknum
         ply
         dey
         cpy #$00
         bne ]blklp
         jmp ]loadlp
ret      rts
params   db  $03
         db  $01
buffer   adrl $0
blknum   adrl $0
pend     =   *

Compares with zero are for clarity. The interesting thing is that I jump to $9478 instead of $9400, which means I jump over the rewriting of the toolbox vectors. If I jump straight to $9400, the loader will crash about halfway through on my ROM 3 + CFFA3000, although it runs fine in an emulator. Does CFFA3000 extended smartport call invoke tools? Maybe, too lazy to find out right now. Also I don't derive $C50D properly, which is fine in this case because the target interface is known (CFFA card).

Used Block Warden to Follow the assembled Merlin output, then Change to slot5 drive1, then Write it to block $0600 of the Modulae disk.

Booting this on ROM 3 + CFFA3000 results in lack of "And now, FTA presents" sound because I did not add that back in. It's part of the old loader and could be re-added if it bothers you though (see $9785). Next, you do see a scroll of disk blocks loading at memory addresses, a momentary pause for decrunching, and finally THE AUDIENCE IS READING.

Download patched Modulae image (right-click, Save As, etc)

The XMAS demo works pretty similarly. Am I going to patch it next? Maybe. It could also be fun to re-save this demo as a .S16 or .SYS file. Am I going to do that? Maybe. I promise nothing.

- iigs@ballmerpeak.org